Zmienne i typy danych w ABAP – DATA, TYPE i deklaracje inline

W trzeciej części kursu ABAP zajmiemy się zmiennymi i typami danych. Zobaczymy, co właściwie tworzy instrukcja DATA, czym jest TYPE, skąd biorą się typy takie jak MATNR i dlaczego w nowoczesnym ABAP-ie często spotykamy deklaracje inline.

Uczysz się ABAP? Uczmy się razem!

Sam również uczę się ABAP i systematycznie rozwijam swoje umiejętności, dlatego w tym cyklu pokazuję wszystko krok po kroku i prostym językiem. Nie chcę wrzucać od razu dziesiątek pojęć do zapamiętania. Wolę najpierw zrozumieć, co dana instrukcja robi i po co w ogóle istnieje, a dopiero później dokładać kolejne elementy.

Przykłady sprawdzam w systemie i staram się zestawiać je z dokumentacją SAP oraz zasadami Clean ABAP. Jeżeli dopiero zaczynasz naukę ABAP od podstaw, najlepiej uruchamiaj przykłady razem ze mną i zmieniaj wartości w kodzie. Wtedy teoria bardzo szybko zaczyna mieć sens.

W pierwszej części kursu utworzyliśmy pierwszy program w SE38. W drugiej części rozłożyliśmy program ABAP na najważniejsze elementy i zobaczyliśmy między innymi REPORT, TYPES, DATA, ekran selekcji oraz zdarzenia programu.

Teraz zatrzymamy się przy jednym z tych elementów i przyjrzymy mu się dokładniej.

Po tej lekcji powinieneś wiedzieć:

  • czym jest zmienna w programie ABAP,
  • co oznacza DATA i TYPE,
  • czym różnią się podstawowe typy danych,
  • skąd bierze się typ MATNR,
  • jaka jest różnica pomiędzy TYPE i LIKE,
  • na czym polega deklaracja inline DATA(...),
  • dlaczego w nowych przykładach nie będę na siłę dodawał prefiksów lv_, ls_ czy lt_.

1. Czym właściwie jest zmienna?

Najprościej wyobrazić sobie zmienną jako pudełko na wartość.

Pudełko ma swoją nazwę, a ABAP musi dodatkowo wiedzieć, jaki rodzaj danych wolno do niego włożyć. Czy będzie to liczba, tekst, data, numer materiału, ilość czy jeszcze coś innego.

Najprostsza deklaracja może wyglądać tak:

DATA quantity TYPE i.

W tym jednym wierszu przekazujemy systemowi trzy informacje:

  • DATA – chcemy utworzyć obiekt danych,
  • quantity – tak będzie nazywał się nasz obiekt,
  • TYPE i – obiekt ma przechowywać liczbę całkowitą.

Po deklaracji możemy przypisać wartość:

quantity = 2.

Od tego momentu quantity przechowuje wartość 2.

Deklaracja zmiennej quantity w edytorze ABAP SE38
Rys. 1. Deklaracja zmiennej quantity w edytorze ABAP (SE38).

2. DATA i TYPE – jak czytać deklarację?

Spróbujmy przeczytać tę instrukcję niemal jak zwykłe zdanie:

DATA quantity TYPE i.

Można ją rozumieć jako:

„Utwórz obiekt danych o nazwie quantity i nadaj mu typ i.”

To ważne rozróżnienie, ponieważ w poprzedniej lekcji pojawiło się również TYPES.

TYPES ty_quantity TYPE i.
DATA quantity TYPE ty_quantity.

W uproszczeniu:

Instrukcja Co robi?
TYPES Definiuje typ – czyli pewien wzór danych.
DATA Tworzy konkretny obiekt danych, który może przechowywać wartość.

Możemy wrócić do porównania z pudełkiem: TYPES opisuje, jak pudełko ma wyglądać, natomiast DATA tworzy konkretne pudełko, z którego program może korzystać.

3. Podstawowe typy danych w ABAP

ABAP posiada wiele typów danych. Na tym etapie nie ma sensu uczyć się ich wszystkich na pamięć.

Na początek wystarczy kilka najczęściej spotykanych:

Typ Do czego służy? Przykład
i Liczby całkowite 10
string Tekst o zmiennej długości Hello ABAP
c Tekst o ustalonej długości PL
d Data 20260928
t Czas 213000
p Liczby dziesiętne typu packed number 19.99

Przykładowe deklaracje wyglądają tak:

DATA quantity      TYPE i.
DATA description   TYPE string.
DATA country       TYPE c LENGTH 2.
DATA delivery_date TYPE d.
DATA delivery_time TYPE t.
DATA price         TYPE p LENGTH 8 DECIMALS 2.

Warto zauważyć dwie rzeczy.

W przypadku c możemy określić długość:

DATA country TYPE c LENGTH 2.

A dla typu p możemy dodatkowo określić liczbę miejsc dziesiętnych:

DATA price TYPE p LENGTH 8 DECIMALS 2.

Na razie nie musimy analizować technicznych szczegółów reprezentacji każdego typu.

Najważniejsza zasada brzmi:

typ określa, jakiego rodzaju wartość może przechowywać dany obiekt oraz w jaki sposób ABAP będzie tę wartość interpretował.

4. Wartość początkowa – VALUE

Możemy najpierw zadeklarować zmienną, a dopiero potem przypisać jej wartość:

DATA quantity TYPE i.

quantity = 5.

Ale jeżeli wartość jest znana już podczas deklaracji, możemy użyć dodatku VALUE:

DATA quantity TYPE i VALUE 5.

Podobnie dla tekstu:

DATA description TYPE string VALUE `Sample product`.

Nie oznacza to jeszcze, że wartość jest stała. To nadal zwykła zmienna i później możemy ją zmienić.

quantity = 10.

Jeżeli chcielibyśmy utworzyć wartość, której program nie powinien później zmieniać, używamy CONSTANTS. Ten temat poznaliśmy już krótko w poprzedniej części.

5. Typy z ABAP Dictionary – przykład MATNR

Do tej pory korzystaliśmy z podstawowych typów ABAP, takich jak i czy string.

W prawdziwym kodzie SAP bardzo często zobaczymy jednak coś takiego:

DATA product TYPE matnr.

I tutaj pojawia się bardzo ważna rzecz.

MATNR nie jest jednym z prostych, wbudowanych typów takich jak i czy d. Jest to typ zdefiniowany centralnie w ABAP Dictionary, czyli DDIC.

Dzięki temu zamiast samodzielnie wymyślać długość i właściwości pola numeru materiału, możemy wykorzystać definicję istniejącą już w systemie.

To samo podejście zobaczymy później praktycznie wszędzie: w tabelach bazodanowych, strukturach, interfejsach metod, ekranach czy własnych programach.

Uruchom transakcję SE11 i wyszukaj interesujący Cię typ. W naszym przykładzie będzie to MATNR:

Wyszukiwanie typu MATNR w transakcji SE11
Rys. 2. Wyszukiwanie typu danych MATNR w transakcji SE11.

W ten sam sposób możesz sprawdzać definicje struktur i tabel, a także typy ich poszczególnych pól. Zajrzyjmy więc do definicji MATNR:

Definicja typu MATNR w ABAP Dictionary z długością 40 znaków
Rys. 3. Definicja typu MATNR w ABAP Dictionary – długość 40 znaków.

Na zrzucie ekranu widzimy, że w tym systemie typ MATNR ma postać pola znakowego o długości 40. Definicję warto zawsze sprawdzić w SE11, ponieważ jej parametry zależą od wersji i konfiguracji systemu.

Na razie wystarczy zapamiętać:

TYPE matnr oznacza: użyj typu numeru materiału z ABAP Dictionary. Na pokazanym zrzucie ma on długość 40 znaków; w starszych systemach możesz spotkać długość 18 znaków.

6. TYPE czy LIKE?

W istniejącym kodzie ABAP możemy spotkać zarówno TYPE, jak i LIKE.

Przykład z TYPE:

DATA product TYPE matnr.

Tutaj bezpośrednio wskazujemy typ.

LIKE działa trochę inaczej – tworzy obiekt na podstawie typu innego, istniejącego już obiektu danych.

DATA product_copy LIKE product.

W tym przykładzie product_copy otrzyma właściwości typu obiektu product.

Na początek można zapamiętać bardzo prostą zasadę:

  • TYPE – odnosimy się do typu,
  • LIKE – odnosimy się do istniejącego obiektu danych.

W nowych przykładach będziemy najczęściej korzystać z TYPE. LIKE warto jednak znać, ponieważ pojawia się bardzo często w istniejącym kodzie SAP.

7. Deklaracje inline – DATA(…)

W starszym stylu ABAP często najpierw deklarowano zmienną, a dopiero później używano jej w kodzie:

DATA total TYPE i.

total = 5 + 10.

W nowocześniejszym ABAP-ie w wielu miejscach możemy utworzyć zmienną bezpośrednio tam, gdzie jest potrzebna:

DATA(total) = 5 + 10.

To właśnie deklaracja inline.

ABAP określa typ na podstawie kontekstu i prawej strony przypisania.

Jeszcze prostszy przykład:

DATA(message) = `Hello ABAP!`.

 

Deklaracja inline DATA(message) w kodzie ABAP
Rys. 4. Przykład deklaracji inline DATA(message) w kodzie ABAP.

Deklaracje inline spotkamy później między innymi przy LOOP, wywołaniach metod i instrukcjach SELECT.

Przykład:

LOOP AT products INTO DATA(product).

Na razie nie musimy jeszcze rozumieć samego LOOP. Chodzi jedynie o to, aby oswoić się z zapisem DATA(...).

8. Nazwy zmiennych i Clean ABAP

Jeżeli pracujesz z istniejącymi programami SAP, na pewno zobaczysz nazwy podobne do tych:

DATA lv_quantity TYPE i.
DATA lv_product  TYPE matnr.

Prefiksy takie jak:

Prefiks Najczęstsze znaczenie
lv_ local variable
ls_ local structure
lt_ local internal table
gv_ global variable
gs_ global structure
gt_ global internal table

są bardzo popularne w klasycznym kodzie ABAP i nadal spotkamy je w wielu projektach.

W tej serii będę jednak coraz częściej używał nazw opisujących znaczenie danych:

DATA quantity TYPE i.
DATA product  TYPE matnr.

zamiast:

DATA lv_quantity TYPE i.
DATA lv_product  TYPE matnr.

Dlaczego?

Ponieważ samo lv_ mówi nam głównie, czym technicznie jest zmienna. Nazwa quantity mówi natomiast, co ona oznacza w programie.

To podejście jest zgodne z kierunkiem Clean ABAP: kod powinien przede wszystkim jasno komunikować znaczenie.

Ważne: nie oznacza to, że każdy program używający lv_, ls_ czy lt_ jest „zły”. W istniejących systemach spotkamy różne konwencje. Warto je rozumieć, a w nowym kodzie przede wszystkim dbać o czytelność i zasady przyjęte w konkretnym projekcie.

9. Budujemy mały program w SE38

Czas połączyć teorię w jednym przykładzie.

Utwórz w SE38 program:

ZABAP_LEKCJA_03

i wklej następujący kod:

REPORT zabap_lekcja_03.

DATA product     TYPE matnr VALUE '100000'.
DATA quantity    TYPE i VALUE 5.
DATA price       TYPE p LENGTH 8 DECIMALS 2 VALUE '19.99'.
DATA description TYPE string VALUE `Sample product`.
DATA today       TYPE d.
DATA total_value TYPE p LENGTH 8 DECIMALS 2.

today = sy-datum.
total_value = quantity * price.

DATA(message) = |Product { product }: { quantity } pcs, total { total_value }|.

WRITE: / 'Product:', product,
       / 'Description:', description,
       / 'Quantity:', quantity,
       / 'Price:', price,
       / 'Total:', total_value,
       / 'Date:', today,
       / message.
Kompletny program ZABAP_LEKCJA_03 w edytorze ABAP
Rys. 5. Kompletny program ZABAP_LEKCJA_03 w edytorze SE38.

Spójrzmy teraz na najważniejsze fragmenty.

Najpierw tworzymy kilka obiektów danych:

DATA product     TYPE matnr VALUE '100000'.
DATA quantity    TYPE i VALUE 5.
DATA price       TYPE p LENGTH 8 DECIMALS 2 VALUE '19.99'.
DATA description TYPE string VALUE `Sample product`.
DATA today       TYPE d.

Mamy tutaj kilka różnych typów oraz wartości początkowe.

Następnie pobieramy bieżącą datę systemową:

today = sy-datum.

Dalej wykorzystujemy deklarację zgodną z klasycznym zapisem:

DATA total_value TYPE p LENGTH 8 DECIMALS 2.
total_value = quantity * price.

Dlaczego nie stosujemy tu deklaracji inline? W przypadku obliczeń z typem p zapis DATA(total_value) = quantity * price. może spowodować ostrzeżenie. ABAP przyjmie wtedy dla wyniku typ p o długości 8 i zerowej liczbie miejsc po przecinku (P(8,0)). Moglibyśmy więc utracić część dziesiętną wyniku. Dlatego najpierw deklarujemy total_value jako TYPE p LENGTH 8 DECIMALS 2, a dopiero później przypisujemy iloczyn. Dla ilości 5 i ceny 19,99 oczekujemy wyniku 99,95. To praktyczny przykład pokazujący, że deklaracje inline nie zawsze są dobrym rozwiązaniem.

Kolejny fragment:

DATA(message) =
  |Product { product }: { quantity } pcs, total { total_value }|.

wykorzystuje string template. Znaki | ... | pozwalają zbudować tekst i wstawiać do niego wartości zmiennych za pomocą nawiasów klamrowych.

Nie będziemy teraz dokładnie analizować string templates. W tym miejscu wykorzystujemy je tylko jako prosty przykład pokazujący, gdzie deklaracja inline jest wygodna.

Na końcu instrukcja WRITE wyświetla dane:

WRITE: / 'Product:',     product,
       / 'Description:', description,
       / 'Quantity:',    quantity,
       / 'Price:',       price,
       / 'Total:',       total_value,
       / 'Date:',        today,
       / message.

Zapisz program, sprawdź składnię, aktywuj go i uruchom klawiszem F8.

Wynik działania przykładowego programu w SAP
Rys. 6. Wynik uruchomienia programu ZABAP_LEKCJA_03.

10. Mały eksperyment

Najwięcej można nauczyć się wtedy, kiedy zaczniemy trochę psuć własny kod. 🙂

Zmień:

DATA quantity TYPE i VALUE 5.

na:

DATA quantity TYPE i VALUE 10.

Uruchom program ponownie.

Co stało się z total_value?

Teraz zmień cenę:

DATA price TYPE p LENGTH 8 DECIMALS 2 VALUE '25.50'.

Uruchom program jeszcze raz.

W ten sposób widzimy bardzo prosty, ale ważny mechanizm:

  1. obiekty danych przechowują wartości,
  2. program wykonuje operacje na tych wartościach,
  3. wynik może trafić do kolejnego obiektu danych,
  4. zmiana wartości wejściowych wpływa na wynik programu.

11. Najczęstsze błędy początkujących

Na koniec kilka drobiazgów, które bardzo łatwo przeoczyć.

Brak kropki

Każda instrukcja ABAP kończy się kropką:

DATA quantity TYPE i.

Jeżeli jej zabraknie, kontrola składni zgłosi błąd.

Pomieszanie TYPES i DATA

To dwie różne rzeczy:

TYPES ty_quantity TYPE i.
DATA quantity TYPE ty_quantity.

TYPES definiuje typ. DATA tworzy obiekt danych.

Próba włożenia niewłaściwej wartości do typu

Jeżeli zadeklarujemy liczbę:

DATA quantity TYPE i.

to powinniśmy traktować ją jako liczbę, a nie miejsce na dowolny tekst.

Typ danych nie jest ozdobą deklaracji. To informacja, dzięki której ABAP wie, jak ma interpretować dany obiekt.

Próba nauczenia się wszystkich typów na pamięć

Nie ma takiej potrzeby.

Na początku ważniejsze jest zrozumienie mechanizmu:

DATA nazwa TYPE typ.

Resztę będziemy poznawać w praktyce.

12. Podsumowanie

Po tej lekcji powinniśmy już rozumieć, co dzieje się w bardzo prostych deklaracjach takich jak:

DATA quantity TYPE i.
DATA product TYPE matnr.
DATA(message) = `Hello ABAP!`.

Najważniejsze rzeczy do zapamiętania:

  • DATA tworzy obiekt danych,
  • TYPE określa jego typ,
  • ABAP posiada własne typy elementarne, takie jak i, d, t, c, string czy p,
  • w SAP często korzystamy również z typów zdefiniowanych centralnie w DDIC, np. MATNR,
  • LIKE może przejąć typ istniejącego obiektu danych,
  • VALUE pozwala nadać wartość początkową,
  • deklaracja inline DATA(...) pozwala utworzyć zmienną bezpośrednio w miejscu użycia,
  • czytelna nazwa zmiennej jest ważniejsza niż mechaniczne dokładanie prefiksów.

Jeżeli te rzeczy są już w miarę jasne, mamy bardzo dobry fundament pod kolejny temat.

Co dalej?

W następnej części zajmiemy się strukturami i tabelami wewnętrznymi.

Źródła i dokumentacja

Przygotowując lekcję, opierałem się na dokumentacji SAP i oficjalnym przewodniku Clean ABAP. Najważniejsze odnośniki:

Do tej pory nasze „pudełka” przechowywały pojedyncze wartości. Ale co, jeżeli dla jednego produktu chcemy przechowywać jednocześnie numer materiału, opis, ilość i cenę?

Wtedy zaczyna się temat struktur.

A kiedy takich produktów będziemy mieli dziesięć, sto albo tysiąc – pojawią się tabele wewnętrzne.

I właśnie od tego zaczniemy kolejną lekcję. 🙂

Chcesz być informowany o nowych wpisach?

Ja nie spamuje! Przeczytaj zasady polityki prywatności tego bloga.

0 0 głosy
Article Rating
Subskrybuj
Powiadom o
guest
0 komentarzy
Najstarsze
Najnowsze Najwięcej głosów
0
Chętnie poznam Twoje przemyślenia, skomentuj.x